¿Cómo puedo forzar a Windows a buscar actualizaciones?

Además de la forma habitual de utilizar Windows Update, puede forzar una comprobación desde una línea de comandos.

Abra una línea de comandos de administrador y ejecute:

C:\> %windir%\system32\wuauclt.exe /detectnow

Wuauclt.exe es el cliente de AutoUpdate de Windows Update y se utiliza para comprobar las actualizaciones disponibles (para las distintas versiones de la plataforma MS Windows) desde Microsoft Update.

Esto no forzará una instalación.

Puede comprobar e instalar las actualizaciones automáticamente mediante un script. Esto funcionará tanto en XP como en Windows 7.

Hay varios scripts disponibles para descargar, aquí está el mío :

' Written in 2007 by Harry Johnston, University of Waikato, New Zealand.
' This code has been placed in the public domain. It may be freely
' used, modified, and distributed. However it is provided with no
' warranty, either express or implied.
'
' Exit Codes:
' 0 = scripting failure
' 1 = error obtaining or installing updates
' 2 = installation successful, no further updates to install
' 3 = reboot needed; rerun script after reboot
'
' Note that exit code 0 has to indicate failure because that is what
' is returned if a scripting error is raised.
'

Set updateSession = CreateObject("Microsoft.Update.Session")

Set updateSearcher = updateSession.CreateUpdateSearcher()
Set updateDownloader = updateSession.CreateUpdateDownloader()
Set updateInstaller = updateSession.CreateUpdateInstaller()

Do

  WScript.Echo
  WScript.Echo "Searching for approved updates ..."
  WScript.Echo

  Set updateSearch = updateSearcher.Search("IsInstalled=0")

  If updateSearch.ResultCode <> 2 Then

    WScript.Echo "Search failed with result code", updateSearch.ResultCode
    WScript.Quit 1

  End If

  If updateSearch.Updates.Count = 0 Then

    WScript.Echo "There are no updates to install."
    WScript.Quit 2

  End If

  Set updateList = updateSearch.Updates

  For I = 0 to updateSearch.Updates.Count - 1

    Set update = updateList.Item(I)

    WScript.Echo "Update found:", update.Title

  Next

  WScript.Echo

  updateDownloader.Updates = updateList
  updateDownloader.Priority = 3

  Set downloadResult = updateDownloader.Download()

  If downloadResult.ResultCode <> 2 Then

    WScript.Echo "Download failed with result code", downloadResult.ResultCode
    WScript.Echo

    WScript.Quit 1

  End If

  WScript.Echo "Download complete. Installing updates ..."
  WScript.Echo

  updateInstaller.Updates = updateList

  Set installationResult = updateInstaller.Install()

  If installationResult.ResultCode <> 2 Then

    WScript.Echo "Installation failed with result code", installationResult.ResultCode

    For I = 0 to updateList.Count - 1

      Set updateInstallationResult = installationResult.GetUpdateResult(I)
      WScript.Echo "Result for " & updateList.Item(I).Title & " is " & installationResult.GetUpdateResult(I).ResultCode

    Next

    WScript.Quit 1

  End If

  If installationResult.RebootRequired Then

    WScript.Echo "The system must be rebooted to complete installation."

    WScript.Quit 3

  End If

  WScript.Echo "Installation complete."

Loop

Lo ejecutas desde la línea de comandos así:

cscript wsusupdate.vbs

Mi script es mínimamente funcional pero puede ser útil. Hay otros scripts de este tipo disponibles con muchas características adicionales, intente una búsqueda en Google.

Para comprobar si hay actualizaciones, vaya al Panel de control, Seguridad, Windows Update y haga clic en “Buscar actualizaciones”.

Otra forma de forzar una verdadera re-exploración en busca de actualizaciones es hacer borrón y cuenta nueva, eliminando todas las actualizaciones almacenadas en %windir%\Windows\SoftwareDistribution\Download :

NET STOP wuauserv
    RD /S /Q %windir%\SoftwareDistribution\Download
    NET START wuauserv

A continuación, vaya a Windows Update, y “Buscar actualizaciones”. Puede tardar una hora, porque se comprueban todos los archivos actualizables del volumen del sistema (las siguientes “Comprobaciones de actualizaciones” serán rápidas). Este enfoque elimina los errores, las actualizaciones chapuceras, y produce un sistema limpio y actualizado, al menos en la medida en que MS lo ve.

estoy usando una herramienta de segunda parte llamada wuinstall para la actualización de la instalación de windows fresco. con eso se puede automatizar todo el proceso de actualización, incluyendo los reinicios automáticos. creo que es una de las maneras más rápidas de obtener un windows fresco actualizado sin la asistencia del usuario.

He descubierto que si, como parte de la instalación nueva en Windows 7, actualizaste IE o no has ejecutado IE todavía y respondido a las preguntas introductorias, Windows Update te dará un error. Tampoco he encontrado una manera de cambiar Windows Update a Microsoft Update sin pasar por la interfaz gráfica de usuario, por lo que manualmente inicio IE, lo inicializo y luego configuro Windows Update a través de la interfaz gráfica de usuario, para poder cambiar a Microsoft Update y evitar el error inicial. Tu experiencia puede variar.

Tuve éxito siguiendo los pasos de este post , al instalar IE8 & WI4.5 , se activan las actualizaciones automáticas para iniciar las descargas.