Comparación de cadenas de texto similares en Excel

Podría considerar usar el Microsoft Fuzzy Lookup Addin .

Del sitio de MS:

Descripción general

El complemento Fuzzy Lookup para Excel fue desarrollado por Microsoft Research y realiza comparaciones difusas de datos textuales en Microsoft Excel. Puede utilizarse para identificar filas duplicadas difusas dentro de una misma tabla o para unir difusamente filas similares entre dos tablas diferentes. El cotejo es robusto frente a una gran variedad de errores, como faltas de ortografía, abreviaturas, sinónimos y datos añadidos o ausentes. Por ejemplo, puede detectar que las filas “Sr. Andrew Hill”, “Hill, Andrew R.” y “Andy Hill” se refieren a la misma entidad subyacente, devolviendo una puntuación de similitud junto con cada coincidencia. Aunque la configuración por defecto funciona bien para una amplia variedad de datos textuales, como los nombres de los productos o las direcciones de los clientes, la coincidencia también puede personalizarse para dominios o idiomas específicos.

Yo consideraría el uso de esta lista (sólo en la sección inglesa) para ayudar a eliminar los acortamientos comunes.

Además, podría considerar el uso de una función que le diga, en términos exactos, lo “cerca” que están dos cadenas. El siguiente código proviene de aquí y gracias a smirkingman .

Option Explicit
Public Function Levenshtein(s1 As String, s2 As String)

Dim i As Integer
Dim j As Integer
Dim l1 As Integer
Dim l2 As Integer
Dim d() As Integer
Dim min1 As Integer
Dim min2 As Integer

l1 = Len(s1)
l2 = Len(s2)
ReDim d(l1, l2)
For i = 0 To l1
    d(i, 0) = i
Next
For j = 0 To l2
    d(0, j) = j
Next
For i = 1 To l1
    For j = 1 To l2
        If Mid(s1, i, 1) = Mid(s2, j, 1) Then
            d(i, j) = d(i - 1, j - 1)
        Else
            min1 = d(i - 1, j) + 1
            min2 = d(i, j - 1) + 1
            If min2 < min1 Then
                min1 = min2
            End If
            min2 = d(i - 1, j - 1) + 1
            If min2 < min1 Then
                min1 = min2
            End If
            d(i, j) = min1
        End If
    Next
Next
Levenshtein = d(l1, l2)
End Function

Lo que esto hará es decirte cuántas inserciones y eliminaciones hay que hacer a una cadena para llegar a la otra. Yo trataría de mantener este número bajo (y los apellidos deben ser exactos).

Tengo una fórmula (larga) que puedes utilizar. No está tan bien perfeccionada como las anteriores -y sólo funciona para el apellido, en lugar de un nombre completo-, pero puede resultarle útil.

Así que si tienes una fila de cabecera y quieres comparar A2 con B2, coloca esto en cualquier otra celda de esa fila (por ejemplo, C2) y copia hasta el final.

=IF(A2=B2, “EXACTO”,IF(SUBSTITUTE(A2,“-”,“ ”)=SUBSTITUTE(B2,“-”,“ ”), “Guión”,IF(LEN(A2)\N>LEN(B2),IF(LEN(A2)\N>LEN(SUBSTITUTE(A2,B2,“”)), “Cadena completa”,IF(MID(A2,1, 1)=MID(B2,1,1),1,0)+IF(MID(A2,2,1)=MID(B2,2,1),1,0)+IF(MID(A2,3,1)=MID(B2,3,1),1,0)+IF(MID(A2,LEN(A2),1)=MID(B2,LEN(B2),1),1,0)+IF(MID(A2,LEN(A2)-1,1)=MID(B2,LEN(B2)-1,1),1, 0)+IF(MID(A2,LEN(A2)-2,1)=MID(B2,LEN(B2)-2,1),1,0)&“°”),IF(LEN(B2)>LEN(SUBSTITUTE(B2,A2,“”)), “Cadena completa”,IF(MID(A2,1,1)=MID(B2,1,1),1,0)+IF(MID(A2,2,1)=MID(B2,2,1),1, 0)+IF(MID(A2,3,1)=MID(B2,3,1),1,0)+IF(MID(A2,LEN(A2),1)=MID(B2,LEN(B2),1),1,0)+IF(MID(A2,LEN(A2)-1,1)=MID(B2,LEN(B2)-1,1),1,0)+IF(MID(A2,LEN(A2)-2,1)=MID(B2,LEN(B2)-2,1),1,0)&“°”))))

Esto devolverá:

• EXACTO - si se trata de una coincidencia exacta
• Guión - si se trata de un par de nombres de doble barra pero uno tiene un guión y el otro un espacio
• Cadena completa - si todo un apellido forma parte del otro (por ejemplo, si un Smith se ha convertido en un French-Smith)

Después le dará un grado de 0° a 6° dependiendo del número de puntos de comparación entre los dos. (es decir, 6° se compara mejor).

Como he dicho, es un poco aproximado, pero espero que te dé una idea aproximada.

Estaba buscando algo similar. Encontré el siguiente código. Espero que esto ayude al próximo usuario que se acerque a esta pregunta

Devuelve el 91% para Abracadabra / Abrakadabra, el 75% para Hollywood Street/Hollyhood Str, el 62% para Florencia/Francia y el 0 para Disneylandia

Yo diría que se acerca bastante a lo que querías :)

Public Function Similarity(ByVal String1 As String, _
    ByVal String2 As String, _
    Optional ByRef RetMatch As String, _
    Optional min_match = 1) As Single
Dim b1() As Byte, b2() As Byte
Dim lngLen1 As Long, lngLen2 As Long
Dim lngResult As Long

If UCase(String1) = UCase(String2) Then
    Similarity = 1
Else:
    lngLen1 = Len(String1)
    lngLen2 = Len(String2)
    If (lngLen1 = 0) Or (lngLen2 = 0) Then
        Similarity = 0
    Else:
        b1() = StrConv(UCase(String1), vbFromUnicode)
        b2() = StrConv(UCase(String2), vbFromUnicode)
        lngResult = Similarity_sub(0, lngLen1 - 1, _
        0, lngLen2 - 1, _
        b1, b2, _
        String1, _
        RetMatch, _
        min_match)
        Erase b1
        Erase b2
        If lngLen1 >= lngLen2 Then
            Similarity = lngResult / lngLen1
        Else
            Similarity = lngResult / lngLen2
        End If
    End If
End If

End Function

Private Function Similarity_sub(ByVal start1 As Long, ByVal end1 As Long, _
                                ByVal start2 As Long, ByVal end2 As Long, _
                                ByRef b1() As Byte, ByRef b2() As Byte, _
                                ByVal FirstString As String, _
                                ByRef RetMatch As String, _
                                ByVal min_match As Long, _
                                Optional recur_level As Integer = 0) As Long
'* CALLED BY: Similarity *(RECURSIVE)

Dim lngCurr1 As Long, lngCurr2 As Long
Dim lngMatchAt1 As Long, lngMatchAt2 As Long
Dim I As Long
Dim lngLongestMatch As Long, lngLocalLongestMatch As Long
Dim strRetMatch1 As String, strRetMatch2 As String

If (start1 > end1) Or (start1 < 0) Or (end1 - start1 + 1 < min_match) _
Or (start2 > end2) Or (start2 < 0) Or (end2 - start2 + 1 < min_match) Then
    Exit Function '(exit if start/end is out of string, or length is too short)
End If

For lngCurr1 = start1 To end1
    For lngCurr2 = start2 To end2
        I = 0
        Do Until b1(lngCurr1 + I) <> b2(lngCurr2 + I)
            I = I + 1
            If I > lngLongestMatch Then
                lngMatchAt1 = lngCurr1
                lngMatchAt2 = lngCurr2
                lngLongestMatch = I
            End If
            If (lngCurr1 + I) > end1 Or (lngCurr2 + I) > end2 Then Exit Do
        Loop
    Next lngCurr2
Next lngCurr1

If lngLongestMatch < min_match Then Exit Function

lngLocalLongestMatch = lngLongestMatch
RetMatch = ""

lngLongestMatch = lngLongestMatch _
+ Similarity_sub(start1, lngMatchAt1 - 1, _
start2, lngMatchAt2 - 1, _
b1, b2, _
FirstString, _
strRetMatch1, _
min_match, _
recur_level + 1)
If strRetMatch1 <> "" Then
    RetMatch = RetMatch & strRetMatch1 & "*"
Else
    RetMatch = RetMatch & IIf(recur_level = 0 _
    And lngLocalLongestMatch > 0 _
    And (lngMatchAt1 > 1 Or lngMatchAt2 > 1) _
    , "*", "")
End If

RetMatch = RetMatch & Mid$(FirstString, lngMatchAt1 + 1, lngLocalLongestMatch)

lngLongestMatch = lngLongestMatch _
+ Similarity_sub(lngMatchAt1 + lngLocalLongestMatch, end1, _
lngMatchAt2 + lngLocalLongestMatch, end2, _
b1, b2, _
FirstString, _
strRetMatch2, _
min_match, _
recur_level + 1)

If strRetMatch2 <> "" Then
    RetMatch = RetMatch & "*" & strRetMatch2
Else
    RetMatch = RetMatch & IIf(recur_level = 0 _
    And lngLocalLongestMatch > 0 _
    And ((lngMatchAt1 + lngLocalLongestMatch < end1) _
    Or (lngMatchAt2 + lngLocalLongestMatch < end2)) _
    , "*", "")
End If

Similarity_sub = lngLongestMatch

End Function

Este código escanea la columna a y la columna b, si encuentra alguna similitud en ambas columnas se muestra en amarillo. Puedes usar el filtro de color para obtener el valor final. No he añadido esa parte en el código.

Sub item_difference()

Range("A1").Select

last_row_all = Range("A65536").End(xlUp).Row
last_row_new = Range("B65536").End(xlUp).Row

Range("A1:B" & last_row_new).Select
With Selection.Interior
    .Pattern = xlSolid
    .PatternColorIndex = xlAutomatic
    .Color = 65535
    .TintAndShade = 0
    .PatternTintAndShade = 0
End With

For i = 1 To last_row_new
For j = 1 To last_row_all

If Range("A" & i).Value = Range("A" & j).Value Then

Range("A" & i & ":B" & i).Select
With Selection.Interior
    .Pattern = xlSolid
    .PatternColorIndex = xlAutomatic
    .ThemeColor = xlThemeColorDark1
    .TintAndShade = 0
  .PatternTintAndShade = 0
End With

End If
Next j
Next i
End Sub

Aunque mi solución no permite identificar cadenas muy diferentes, es útil para la coincidencia parcial (coincidencia de subcadenas), por ejemplo, “esto es una cadena” y “una cadena” resultará como “coincidente”:

sólo hay que añadir “*” antes y después de la cadena a buscar en la tabla.

Fórmula habitual:

• vlookup(A1,B1:B10,1,0)
• cerca.vert(A1;B1:B10;1;0)

se convierte en

• vlookup(“*” & A1 & “*”,B1:B10;1,0)
• cerca. vert(“*” & A1 & “*”;B1:B10;1;0)

“&” es la “versión corta” de concatenar()

Puede utilizar la función de similitud (pwrSIMILARITY) para comparar las cadenas y obtener un porcentaje de coincidencia de las dos. Puede hacer que distinga entre mayúsculas y minúsculas o no. Tendrá que decidir qué porcentaje de coincidencia es “suficientemente cercano” para sus necesidades.

Hay una página de referencia en http://officepowerups.com/help-support/excel-function-reference/excel-text-analyzer/pwrsimilarity/ .

Pero funciona bastante bien para comparar el texto de la columna A con el de la columna B.