Listar archivos de forma recursiva mostrando sólo la ruta completa y el tamaño del archivo desde el Símbolo del sistema de Windows

Esto debería servir:

@echo off & for /f %a in ('dir /s /b') do echo %~fa %~za

No es muy eficiente… ejecutarlo para carpetas que contengan una tonelada de archivos puede ser poco preciso, así que pruébalo en carpetas pequeñas primero.

Del texto de ayuda “for /?” (he usado ‘a’ en lugar de ‘I’)

In addition, substitution of FOR variable references has been enhanced.
You can now use the following optional syntax:

%~I - expands %I removing any surrounding quotes (")
%~fI - expands %I to a fully qualified path name
%~dI - expands %I to a drive letter only
%~pI - expands %I to a path only
%~nI - expands %I to a file name only
%~xI - expands %I to a file extension only
%~sI - expanded path contains short names only
%~aI - expands %I to file attributes of file
%~tI - expands %I to date/time of file
%~zI - expands %I to size of file
%~$PATH:I - searches the directories listed in the PATH
               environment variable and expands %I to the
               fully qualified name of the first one found.
               If the environment variable name is not
               defined or the file is not found by the
               search, then this modifier expands to the
               empty string

The modifiers can be combined to get compound results:

%~dpI - expands %I to a drive letter and path only
%~nxI - expands %I to a file name and extension only
%~fsI - expands %I to a full path name with short names only
%~dp$PATH:I - searches the directories listed in the PATH
               environment variable for %I and expands to the
               drive letter and path of the first one found.
%~ftzaI - expands %I to a DIR like output line

La alternativa #1: FOR /R es más intuitiva que la #2 para mí.
La alternativa #2: FOR /F soluciona el problema de los “espacios en los nombres” de la sugerencia de BrianAdkins.
Alternativa #3: FORFILES sería mi elección excepto que la ruta está entre comillas dobles.

Brian u otros gurús pueden tener una solución más elegante o pueden ser capaces de sugerir una docena de otras soluciones, pero estas tres funcionan. Intenté usar FOR TOKENS pero luego tuve que quitar los encabezados y los pies de página así que volví al #1. También consideré crear un pequeño archivo .bat y llamarlo, pero eso añade otro archivo (aunque proporciona mayor flexibilidad, como lo haría una función).

Probé todas las alternativas con nombres de directorios y archivos con espacios incrustados, un nombre de archivo de más de 200 caracteres, un nombre de archivo sin extensión, y en la raíz de una unidad pequeña (sólo por el tiempo; un poco lento – tal como sugirió Brian – pero también lo es la búsqueda en el Explorador de Windows; por eso instalé la aplicación de búsqueda Everything).

Alternativa #1: FOR /R

Mejor(?) Mientras intentaba averiguar por qué la solución de Brian no me funcionaba, miré en HELP FOR y decidí probar el enfoque /R. (Crear un archivo sería lo mismo que en la alternativa #2. )

@echo off & for /R "c:\deletelater\folder with spaces" %A in (*.*) do echo %~fA %~zA

Ejemplo - Funciona (directorio diferente al anterior para demostrar la recursividad)

@echo off & for /R "c:\deletelater" %A in (*.*) do echo %~fA %~zA
c:\DeleteLater\Name with Spaces.txt 19800676
c:\DeleteLater\NoSpacesLongName.txt 21745440
c:\DeleteLater\Folder with Spacesnd Name with Spaces.txt 5805492
c:\DeleteLater\Folder with SpacesndNoSpacesLongName.txt 3870322
c:\DeleteLater\FolderNoSpacesrd Name with Spaces.txt 27874695
c:\DeleteLater\FolderNoSpacesrdNoSpacesLongName.txt 28726032

Alternativa #2: FOR /F

Sugirió BrianAdkins: @echo off & for /f %a in ('dir /s /b') do echo %~fa %~za

Una respuesta corregida es:

@echo off & for /f "delims=*" %A in ('dir /s /b') do echo %~fA %~zA

Una respuesta más completa con los directorios suprimidos y la salida (anexada) a un archivo es:

@echo Results on %DATE% for %CD% >> YourDirFile.txt & echo off & for /f "delims=*" %A in ('dir /s /b /a:-d') do echo %~fA %~zA >> YourDirFile.txt

Nota: “delims=*” especifica un carácter no permitido en los nombres de archivos.
Nota: El segundo comando también suprime los directorios mediante /a:-d.
Nota: Se ha puesto el nombre de la variable FOR en mayúsculas para aclarar la distinción entre la variable y los parámetros de la variable si alguien elige nombres de variables diferentes.
Nota: Añadido al archivo sólo para sonreír, ya que el OP pidió la salida a un archivo.

Supongo que debería comprobar el estado de ECHO y reiniciarlo también.

Issue - Spaces in Names

La solución propuesta por Brian no maneja los nombres de archivos y carpetas que contienen espacios (al menos no en mi configuración de Vista).

Ejemplo - Incorrecto(Sin delims; Incluye la supresión del directorio por OP pero con el tamaño antes y después del nombre del archivo para enfatizar)

Nombre y tamaño truncados (4 de 6 archivos incorrectos):

@echo off & for /f %A in ('dir /s /b /a:-d') do echo %~zA %~fA %~zA
 C:\DeleteLater\Name
21745440 C:\DeleteLater\NoSpacesLongName.txt 21745440
 C:\DeleteLater\Folder
 C:\DeleteLater\Folder
 C:\DeleteLater\FolderNoSpacesrd
28726032 C:\DeleteLater\FolderNoSpacesrdNoSpacesLongName.txt 28726032

Ejemplo - Correcto(Observe la salida a pantalla, no se anexa al archivo)

@echo off & for /f "delims=*" %A in ('dir /s /b /a:-d') do echo %~fA %~zA
C:\DeleteLater\Name with Spaces.txt 19800676
C:\DeleteLater\NoSpacesLongName.txt 21745440
C:\DeleteLater\Folder with Spacesnd Name with Spaces.txt 5805492
C:\DeleteLater\Folder with SpacesndNoSpacesLongName.txt 3870322
C:\DeleteLater\FolderNoSpacesrd Name with Spaces.txt 27874695
C:\DeleteLater\FolderNoSpacesrdNoSpacesLongName.txt 28726032

Alternativa #3: FORFILES (Problema de cita)

Esta solución es directa de los dos últimos ejemplos en la documentación de FORFILES (forfiles /?).

FORFILES /S /M *.doc /C "cmd /c echo @fsize"
FORFILES /M *.txt /C "cmd /c if @isdir==FALSE notepad.exe @file"

Combinando estos ejemplos y escribiendo en un fichero se obtiene la respuesta (casi):

forfiles /s /c "cmd /c if @isdir==FALSE echo @path @fsize" >>ForfilesOut.txt

Observe que la ruta está entre comillas en la salida.
No importa si se activa echo on o echo off.
Añadir una línea en blanco separando cada directorio sería una extensión trivial del IF.

Atención_ : ¡El uso de la máscara /m *.* no devolverá archivos sin extensión (como el último archivo del ejemplo)!

Aside : Esto escribe un archivo en cada directorio con el contenido de sólo ese directorio:
forfiles /s /c "cmd /c if @isdir==FALSE echo @path @fsize >>ForfilesSubOut.txt" No es lo que el OP quería pero a veces es útil.

Ejemplo - Funciona (pero con el fullpath entre comillas)

forfiles /s /c "cmd /c if @isdir==FALSE echo @path @fsize"

"c:\DeleteLater\Name with Spaces.txt" 19800676
"c:\DeleteLater\NoSpacesLongName.txt" 21745440
"c:\DeleteLater\Folder with Spacesnd Name with Spaces.txt" 5805492
"c:\DeleteLater\Folder with SpacesndNoSpacesLongName.txt" 3870322
"c:\DeleteLater\FolderNoSpacesrd Name with Spaces.txt" 27874695
"c:\DeleteLater\FolderNoSpacesrdNoSpacesLongName.txt" 28726032
"c:\DeleteLater\MoreFiles\A really really long file name that goes on and on 123456789 asdfghjkl zxcvnm qwertyuiop and still A really really long file name that goes on and on 123456789 qwertyuiop and still further roughly 225 characters by now.txt" 447
"c:\DeleteLater\MoreFiles\New Text Document no extension" 0

Este ejemplo incluye un directorio extra con un nombre de archivo súper largo y un nombre de archivo sin extensión.

Asunto: Path in Quotes

Así que, ¿hay una manera fácil de eliminar las comillas no deseadas(?) según el ejemplo OP y guardar la alternativa #3: FORFILES. (Pregunta retórica: ¿Las comillas son una característica o un defecto?)

powershell "dir | select name,length"

Esto puede ser una trampa para la pregunta de la OP. Sin embargo, la pregunta ya no es relevante en los sistemas modernos basados en Windows. El alias Dir se utilizó para ayudar a dibujar el enlace lógico.

Me doy cuenta de que esto requiere una utlidad extra_, pero puedes conseguirlo de forma bastante sucinta usando la utilidad sfk :

sfk cwd +run -yes "sfk list -size -tab $qfile +toclip"

sfk fromclip > C:\_temp\sfk_list_output.txt

(Yo conseguí la aproximación usando sfk command chaining here )

El comando “du” me parece bastante útil y funciona tanto en Windows como en Unix (lo usé para comprobar si todos los archivos se habían copiado al transferir muchos datos de un PC con Windows a un servidor web con Linux):

du -ah "C:\your_dir" > "C:\file_list.txt"

salidas:

15 C:\your_dir/.htaccess
608 C:\your_dir/folder/hello.txt
1.0 C:\your_dir/folder/subfolder/test.txt
1.0 C:\your_dir/folder/subfolder
1.2M C:\your_dir/folder/world.txt
1.2M C:\your_dir/folder
9.0 C:\your_dir/no_file_ending
11 C:\your_dir/sample document 1.txt
684K C:\your_dir/sample document 2 - äöüßÄÖÜáà.txt
1.9M C:\your_dir

Sin embargo, sólo pude ver correctamente los caracteres especiales en el Bloc de notas, no en el Bloc de notas++ (debe ser algún asunto de codificación ANSI/UTF-8, no tengo tiempo de analizarlo exactamente ahora). Tampoco encontré una solución para mostrar el tamaño después del nombre del archivo. Usa las opciones “b” o “k” en lugar de “h” para mostrar el tamaño en bytes o kilobytes. Tuve algunos problemas al ejecutar el comando fuera de la carpeta que quiero analizar. Así que lo mejor es introducir el comando en el directorio correcto (“C:\Nsu_dir” en este ejemplo) y especificarlo en el comando.

A continuación se muestra lo que utilicé para localizar archivos de vídeo diversos que ocupaban demasiado espacio en una unidad de red y escribir los resultados en un archivo de texto en un PC local.

Estoy publicando mi propia respuesta algo tardía por tres razones. Una, me gustan las respuestas concisas. Dos, esta única línea de script me ha funcionado en múltiples configuraciones, incluso a través de una red. Tres, por el comentario potencialmente oscuro de Don Vince bajo la respuesta de BrianAdkins, el uso de tokens puede evitar los problemas de los nombres de archivo con espacios en ellos.

for /f "tokens=*" %%a in ('dir H:\*.mov H:\*.avi H:\*.wmv H:\*.mp4 /s /b') do echo %%~fa %%~za >> C:\Temp\VideoList.txt

Me he dado cuenta de que las rutas/nombres de archivo muy largos (cientos de caracteres) también pueden causar errores, pero la búsqueda no se bloquea en ellos. Sin embargo, la ruta sigue sin ser explorada completamente para su(s) objetivo(s). Una vez anotado, puede compensar comenzando más profundamente en la estructura de carpetas para eliminar este error.

Esta página ss64 tiene una muy buena presentación del uso del comando dir, listando todos los interruptores, muchas combinaciones de interruptores, y mostrando varios ejemplos útiles de la sintaxis correcta. No es tan completa como las diversas comunidades de Stack Exchange, pero hay una claridad definitiva en la presentación una vez que te sientes cómodo con la línea de comandos / scripting por lotes.

He llegado a esto con el siguiente comando:

(for /R "\path\to\directory\" %A in (*.*) do echo %~fA %~zA) | findstr /v "echo"

El resultado:

D:\Users\Natasha>(for /R ".\" %A in (*.*) do echo %~fA %~zA) | findstr /v "echo"

D:\Users\Natasha\Flowers_ (12).jpg 118886

D:\Users\Natasha\SomeFolder\data.txt 1241

D:\Users\Natasha\SomeFolder\CS\Counter-Strike_1.6.exe 272645624

P.D. Esto se basa en la respuesta de BillR (Alternativa #1). Sin embargo en mi caso se cuelga con @echo off.

Omita la b en dir /b /s /a:-D > results.txt y los resultados deberían ser como, (es decir dir /s/a: -D > results.txt):

El volumen en la unidad H es FILES El número de serie del volumen es C9EB-112E

Directorio de H:\Files

09/29/2014 11:36 PM 0 testing. txt 1 Archivo(s) 0 bytes

Directorio de H:\Video\Action\Comix

10/06/2012 09:51 AM 184,740 file1.txt 07/20/2012 06:21 AM 864,832 file2.txt 08/31/2009 08:47 PM 606,638 file3.txt 08/31/2009 09:07 PM 160,320 file4.txt

where * /t

Sin complicarse demasiado, esto debería producir la salida deseada. Dará un poco más de lo que el OP pidió, pero pensé que valía la pena mencionarlo. Agregue el interruptor /R para especificar un directorio diferente al actual.